/**
 * Name: feffit
 * Description: feffit input files
 * Author: Bruce Ravel <ravel@phys.washington.edu>
 */

/* Put this file in your ~/.enscript/ directory and try running
 *   enscript -Efeffit <input_file>
 *                                                 for b&w hardcopy
 *   enscript -Efeffit --color==1 <input_file>
 *                                                 for color hardcopy
 *   enscript -Efeffit --color==1 -Whtml -o foo.html <input_file>
 *                                                 for html
 */

state feffit extends HighlightEntry
{
  /* Comments. */
  /[#%!]/ {
    comment_face (true);
    language_print ($0);
    call (eat_one_line);
    comment_face (false);
  }
  /^[ \t]*\*/ {
    comment_face (true);
    language_print ($0);
    call (eat_one_line);
    comment_face (false);
  }

  /* String constants. */
  /\btitle\b/i {
    string_face (true);
    language_print ($0);
    call (eat_one_line);
    string_face (false);
  }

  /* Path parameters: */

  /^[ \t]*(path|feff|id|s[0os]2|amp|e[0ei]|e0?shift|d?phase|del(ta)?r\
|sigma2|dwf|3rd|third|cubic|4th|fourth|quartic)\b/i {
    variable_name_face (true);
    language_print ($0);
    variable_name_face (false);
  }

  /* feffit i/o keywords, reff, set, guess, local: */

  /\b(bkgfile|data|end|guess|include|(next data set)|out|quit|reff)\b[^\/]/i {
    reference_face (true);
    language_print ($0);
    reference_face (false);
  }
  /^[ \t]*\b(guess|local|set)\b/i {
    reference_face (true);
    language_print ($0);
    reference_face (false);
  }


  /* feffit keywords: */

  /\b(all(|out)|bkg(|out)|co(mment|rmin)|d([kqr]|egen|k[12]|q[12]|r[12])\
|e(nvout|ps(ilon|kr)|spr)|f(orm(at|in|out)|ullk)|i(kwindow|print\
|rwindow|window)|k(full|m(ax|in)|sp(fit|out)|w(|eight))\
|m(docxx|ft(fit|wrt))|no(degen|fit|out|run)|p(c(fit|out)|rmout)\
|q(m(ax|in)|sp(fit|out)|w(|eight))|r(last|m(ax|in)|sp(fit|out))\
|si(g(dat|r)|hk)|t(oler|ranquada)|w(|eight))\b/i {
    keyword_face (true);
    language_print ($0);
    keyword_face (false);
  }

}


/*
Local variables:
mode: c
End:
*/